:itemtracker_loopcheck
if exist %itemtracker_simapp%\items.log move %itemtracker_simapp%\items.log core\status\itemslog.txt>nul 2>&1&&call :itemtracker_found item
if exist %itemtracker_simapp%\hats.log move %itemtracker_simapp%\hats.log core\status\hatslog.txt>nul 2>&1&&call :itemtracker_found hat
%itemtracker_simcheck%>nul||call :itemtracker_start
goto :eof
:itemtracker_found
if "%1"=="item" for /f "tokens=* delims=" %%a in ('%sed% -f %itemtracker_itemlist% core\status\itemslog.txt') do call :itemtracker_foundlist itemtracker_itemfound itemtracker_itemfound_list "%%a" item
if "%1"=="hat" for /f "tokens=* delims=" %%a in ('%sed% -f %itemtracker_hatlist% core\status\hatslog.txt') do call :itemtracker_foundlist itemtracker_hatfound itemtracker_hatfound_list "%%a" hat
if "%1"=="item" type core\status\itemslog.txt>>userfiles\itemdrops.log&&echo.>>userfiles\itemdrops.log
if "%1"=="hat" type core\status\hatslog.txt>>userfiles\itemdrops.log&&echo.>>userfiles\itemdrops.log
if %itemtracker_hatfound_total% GEQ 1 set "windowtitle=%windowtitle_stock% -- (%itemtracker_hatfound_total%) HATS - (%itemtracker_itemfound_total%) ITEMS"
if %itemtracker_hatfound_total%==0 set "windowtitle=%windowtitle_stock% -- (%itemtracker_itemfound_total%) ITEMS"
%windowtitle%
if not "%itemtracker_itemnotify%"=="0" if %itemtracker_itemfound% GEQ %itemtracker_itemnotify% call :itemtracker_notify
if not "%itemtracker_hatnofity%"=="0" if %itemtracker_hatfound% GEQ %itemtracker_hatnofity% call :itemtracker_notify
goto :eof
:itemtracker_foundlist
if "%4"=="hat" call :echostatus "           !!!!HAT!!!! - [ %~3 ]"
if "%4"=="item" call :echostatus "                 Found - [ %~3 ]"
call set /a %1+=1
call set /a %1_total+=1
if not defined %2 (call set %2=%~3) else (call set "%2=%%%2%%|%%~3")
goto :eof

:itemtracker_notify
if %itemtracker_notify%==0 goto :eof
set itemtracker_emailsubject=
if %itemtracker_hatfound% GEQ 1 set "itemtracker_emailsubject=FOUND - (%itemtracker_hatfound%)HAT"
if %itemtracker_itemfound% GEQ 1 if defined itemtracker_emailsubject set "itemtracker_emailsubject=%itemtracker_emailsubject% - (%itemtracker_itemfound%)ITEM"
if %itemtracker_itemfound% GEQ 1 if not defined itemtracker_emailsubject set "itemtracker_emailsubject=FOUND - (%itemtracker_itemfound%)ITEM"
if defined itemtracker_hatfound_list set "itemtracker_emailbody=%itemtracker_hatfound_list%"
if defined itemtracker_itemfound_list if not defined itemtracker_emailbody (set "itemtracker_emailbody=%itemtracker_itemfound_list%") else (set "itemtracker_emailbody=%itemtracker_emailbody%|%itemtracker_itemfound_list%")
start /b %itemtracker_sendemail%
set itemtracker_itemfound=0
set itemtracker_hatfound=0
set itemtracker_itemfound_list=
set itemtracker_hatfound_list=
goto :eof

:itemtracker_dropfound_test
set itemtracker_testing=%~1
if not defined itemtracker_testing set itemtracker_testing=Raw Test
set "itemtracker_emailsubject=FOUND - (%itemtracker_testing%)TEST"
set "itemtracker_emailbody=%itemtracker_testing% 1|%itemtracker_testing% 2|%itemtracker_testing% 3|%itemtracker_testing% 4|%itemtracker_testing% 5"
start /b %itemtracker_sendemail%
goto :eof

:itemtracker_readonly
pushd %itemtracker_simapp%
start steamitemmanager.exe -minimized -readonly -nocrashdialog 
popd
goto :eof
:itemtracker_readwrite
pushd %itemtracker_simapp%
start steamitemmanager.exe -minimized -nocrashdialog 
popd
goto :eof
:itemtracker_stop
pushd %itemtracker_simapp%
start steamitemmanager.exe -exit
popd
%wait% 3000
goto :eof
:itemtracker_start
if "%itemtracker_enable%"=="0" goto :eof
if "%itemtracker_readonly%"=="1" (call :itemtracker_readonly) else (call :itemtracker_readwrite)
set itemtracker_enable=1
%wait% 3000
goto :eof
:itemtracker_simmngr
if /i "%~1"=="stop" set "itemtracker_enable=0"&&call :itemtracker_stop&&goto :eof
if /i "%~1"=="start" if "%itemtracker_enable%"=="0" call :itemtracker_start&&goto :eof
if /i "%~1"=="read" if "%itemtracker_readonly%"=="0" set "itemtracker_readonly=1"&&call :itemtracker_stop&&call :itemtracker_start&&goto :eof
if /i "%~1"=="write" if "%itemtracker_readonly%"=="1" set "itemtracker_readonly=0"&&call :itemtracker_stop&&call :itemtracker_start&&goto :eof
echo SIM command is already active, or invalid.
goto :eof

